***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar. 24, 2026                                                        *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJQ5576A-AU     drain  gate  source
Lg     gate  g1    2.2n
Ld     drain d1    100p
Ls     source s1   350p
Rs     s1    s2    205u TC=3m
Rg     g1    g2    1.480
M1     d2    g2    s2    s2    DMOS    L=1u   W=1u
.MODEL DMOS NMOS ( KP=105  VTO=2.65  LEVEL=3  VMAX=5e4 NFS=5e11  GAMMA=1)
Rd     d1    d2   1.210e-2    TC=6.300e-3,12u
Dbd     s2    d2    Dbt
.MODEL   Dbt   D(BV=110  TBV1=5.085e-4 TBV2=-4.430e-7  CJO=8.565e-10  M=6.600e-1  VJ=5.129)
Dbody   s2   21    DBODY
.MODEL DBODY  D(IS=4.011e-13 N=9.585e-1  RS=4e-8  EG=1.15  TT=20n  IKF=1.477)
Rdiode  d1  21    2.710e-3 TC=5.000e-4,13u
.MODEL   sw    NMOS(VTO=0  KP=10   LEVEL=1)
Maux      g2   c    a    a   sw
Maux2     b    d    g2    g2   sw
Eaux      c    a    d2    g2   1
Eaux2     d    g2   d2    g2   -1
Cox       b    d2   6.209e-10
.MODEL     DGD    D(CJO=6.209e-10   M=1.685   VJ=7.669)
Rpar      b    d2   10Meg
Dgd       a    d2   DGD
Rpar2     d2   a    10Meg
Cgs     g2    s2    9.700e-10
.ENDS PJQ5576A-AU
*$
